센스쟁이 프로그래머, 비트센스

'**
' 레코드셋 rs로 xml 만들기
' rs : 레코드셋 객체
' envelopeTag : xml root 태그
' dataTag : 데이터 구분 태그
'* 
Function getPrintXmlData(rs, envelopeTag, dataTag)
	strReturn = "<?xml version=" & chr(34) & "1.0" & chr(34) & " encoding=" & chr(34) & "utf-8" & chr(34) & " ?> " & vbCrLf
	strReturn = strReturn & "<" & envelopeTag & ">" & vbCrLf

	Do While Not rs.EOF
		strReturn = strReturn & "<" & dataTag & ">" & vbCrLf

		For Each f In rs.Fields
			fieldName = f.Name
			fieldValue = rs(fieldName)

			strReturn = strReturn & "    <" & fieldName & "><![CDATA[" & fieldValue & "]]></" & fieldName & ">" & vbCrLf
		Next

		strReturn = strReturn & "</" & dataTag & ">" & vbCrLf
		rs.MoveNext
	Loop

	strReturn = strReturn & "</" & envelopeTag & ">" & vbCrLf

	getPrintXmlData = strReturn
End Function

<% 
Class dbConn
    Private objConn 'as ADODB.Connection
    Public connString
    
    dim DBHost, DBName, DBUser, DBPass
 
    '클래스 생성자
    Sub Class_Initialize()
        Set objConn = Nothing
        
        DBHost = "localhost"
        DBName = "public"
        DBUser = "test"
        DBPass = "test"
        
        connString = "Provider=SQLOLEDB.1;Password=" & DBPass & ";Persist Security Info=False;User ID=" & DBUser & ";Initial Catalog=" & DBName & ";Data Source=" & DBHost
    End Sub
 
    '클래스 소멸자
    Sub Class_Terminate
        Set objConn = Nothing
    End Sub
 
    'Connection 프로퍼티 Get
     Public Property Get Connection() 'as ADODB.Connection
         If objConn Is Nothing Then
             Set objConn = Server.CreateObject("ADODB.Connection")
             objConn.Open connString
         End If

         Set Connection = objConn
     End Property


     '레코드셋 질의
     Public Function ExecuteQuery(strSQL) 'as ADODB.Recordset
        Dim objRs 'as ADODB.Recordset
        Set objRs = Server.CreateObject("ADODB.Recordset")

        
        On Error Resume Next

        objRs.CursorLocation = 3 
        objRs.Open strSQL, Me.Connection, 0

        If Err.Number <> 0 Then
            Response.Write "<b>데이터베이스 에러</b> (ExecuteQuery)<br>" & _
                "질의어 : " & strSQL & _
                Err.Description

            objRs.Close
            Set objRs = Nothing
            Me.Close
            Response.End
        End If

  
        On Error GoTo 0

        Set ExecuteQuery = objRs
    End Function
 
    '업데이트 질의
    Public Sub ExecuteCommand(strSQL)
        On Error Resume Next
  
        Me.Connection.Execute strSQL
  
        If Err.Number <> 0 Then
            Response.Write "<b>데이터베이스 에러</b> (ExecuteCommand)<br>" & _
                "질의어 : " & strSQL & _
                Err.Description
            Response.End
            Me.Close
        End If
   
        On Error GoTo 0
  
    End Sub

    
    '데이터베이스 연결 닫기
    Public Sub Close()
       Set objConn = Nothing
    End Sub
End Class
%>